home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Apple II Magazines (PO)
/
Nibble Volume 10, No. 03 (1989-03)(MicroSPARC)(Side A)[a].zip
/
Nibble Volume 10, No. 03 (1989-03)(MicroSPARC)(Side A)[a].po
/
SETUP.bas
< prev
next >
Wrap
BASIC Source File
|
1996-12-24
|
3KB
|
58 lines
10 REM ************************
20 REM * SETUP *
30 REM * BY PAUL MEYERS *
40 REM * COPYRIGHT (C) 1989 *
50 REM * MICROSPARC, INC. *
60 REM * CONCORD, MA 01742 *
70 REM ************************
80 ONERR GOTO 580
90 IF PEEK(718) < >169 THEN PRINT CHR$(4)"BRUN SUPER.CURSOR": POKE 216,0
100 CALL 718
110 HOME
120 CL = PEEK( -16353)
130 IF CL <127 THEN CW = 40: GOTO 150
140 CW = 80
150 FOR I = 1 TO CW: PRINT "*";: NEXT
160 PRINT "*";: POKE 36, -1 +CW: PRINT "*";
170 PRINT "*";
180 A$ = "SUPER.CURSOR": GOSUB 550
190 POKE 36, -1 +CW: PRINT "*";
200 PRINT "*";:A$ = "By Paul Meyers": GOSUB 550
210 POKE 36, -1 +CW: PRINT "*";
220 PRINT "*";:A$ = "COPYRIGHT (C) 1989": GOSUB 550: POKE 36, -1 +CW: PRINT "*";
230 PRINT "*";:A$ = "MICROSPARC, INC.": GOSUB 550: POKE 36, -1 +CW: PRINT "*";
240 PRINT "*";: POKE 36, -1 +CW: PRINT "*";
250 FOR I = 1 TO CW: PRINT "*";: NEXT
260 PRINT : PRINT
270 POKE 36,0
280 C = PEEK(963): POKE 36,0: VTAB 10: PRINT "The current character is ";: IF C < = 127 THEN C = C +128
290 PRINT CHR$(C)
300 L = PEEK(964): VTAB 11: CALL -868: PRINT "The speed is "L
310 F = PEEK(965): VTAB 12: POKE 36,0: CALL -868: PRINT "The flash option is ";: IF F <128 THEN PRINT "on": GOTO 330
320 PRINT "off"
330 T = PEEK(966): VTAB 13: POKE 36,0: CALL -868: PRINT "The twirl option is ";: IF T >127 THEN PRINT "on": GOTO 350
340 PRINT "off"
350 PRINT : POKE 36,3: PRINT "1-Change character"
360 POKE 36,3: PRINT "2-Change speed"
370 POKE 36,3: PRINT "3-Change flash option"
380 POKE 36,3: PRINT "4-Change twirl option"
390 POKE 36,3: PRINT "5-Quit"
400 VTAB 21: POKE 36,0: CALL -868: PRINT "Please enter choice:";: GET A$: PRINT A$:A = VAL(A$): IF A <1 OR A >5 THEN PRINT CHR$(7): GOTO 400
410 ON A GOTO 420,440,460,490,530
420 GOSUB 570: INPUT "New character value:";N: IF N <0 OR N >255 THEN 420
430 POKE 963,N: GOTO 270
440 GOSUB 570: INPUT "New speed for the cursor:";S: IF S <0 OR S >255 THEN 440
450 POKE 964,S: GOTO 270
460 GOSUB 570: PRINT "Flash on? (Y/N):";: GET F$: IF F$ < >"Y" AND F$ < >"y" AND F$ < >"N" AND F$ < >"n" THEN 460
470 IF F$ = "Y" OR F$ = "y" THEN POKE 965,1: GOTO 270
480 POKE 965,255: GOTO 270
490 GOSUB 570: PRINT "Twirl on? (Y/N):";
500 GET T$: PRINT T$: IF T$ < >"Y" AND T$ < >"y" AND T$ < >"N" AND T$ < >"n" THEN 490
510 IF T$ = "Y" OR T$ = "y" THEN POKE 966,255: GOTO 270
520 POKE 966,1: GOTO 270
530 GOSUB 570: PRINT "Are you sure?";: GET A$: IF A$ = "Y" THEN HOME : POKE 216,0: END
540 POKE 36,0: CALL -868: GOTO 400
550 S = INT((CW - LEN(A$))/2)
560 POKE 36, -1 +S: PRINT A$;: RETURN
570 POKE 36,0: VTAB 21: CALL -868: RETURN
580 HOME : PRINT CHR$(7): PRINT "Disk error": PRINT "Please check disk or replace with disk that contains the file Super.Cursor"